Ausschalttimer

#include <Wire.h>
#include <Adafruit_SSD1306.h>

Adafruit_SSD1306 display(4);

#define DR_INT0   2   // Pin2 für Interrupt 0
#define DR_INT1   3   // Pin3 für Interrupt 1
#define DR_BTN    4   // Pin 4 für den Taster am Drehgeber

#define HOURS_MAX         10                    // maximal einstellbare Ausschalt-Verzögerung in Stunden
#define MINUTES_MAX       HOURS_MAX*60          // maximal einstellbare Ausschalt-Verzögerung in Minuten (8*60=480)
#define SECONDS_MAX       MINUTES_MAX*60        // maximal einstellbare Ausschalt-Verzögerung in Sekunden (480*60=28.800)
#define BAR_WIDTH         120                   // Breite des Balkens in Pixeln
#define MINUTES_PER_STEP  5                     // Schrittweite in Minuten pro Drehgeber-Schritt
#define SECONDS_PER_STEP  MINUTES_PER_STEP*60   // Schrittweite in Sekunden pro Drehgeber-Schritt (4*60=240)

#define RUN_MODE  1
#define SET_MODE  0

#define DEBUG false

// 0=00 (Schritt), 1=01 (rückwärts), 2=10 (vorwärts), 3=11 (Grundstellung)
volatile unsigned char dr_t=0;
volatile int dr_counter=2;

/* -------------------------------------------------------------------------------------------
 */
void dr(void) {
  static unsigned char p;
  switch(p=digitalRead(DR_INT0) | digitalRead(DR_INT1)<<1) {
    case 0:
      if(dr_t==1) {
        dr_t=p;
        if(dr_counter>1)
          dr_counter--;
      } else if(dr_t==2) {
        dr_t=p;
        if(dr_counter<BAR_WIDTH)
          dr_counter++;
      }
      break;
    case 1:
    case 2:
      if(dr_t==3) dr_t=p;
      break;
    case 3:
      dr_t=p;
  }
}

/* -------------------------------------------------------------------------------------------
 */
void dr_start(void) {
  attachInterrupt(digitalPinToInterrupt(DR_INT0), dr, CHANGE);
  attachInterrupt(digitalPinToInterrupt(DR_INT1), dr, CHANGE);
}

/* -------------------------------------------------------------------------------------------
 */
void dr_stop(void) {
  detachInterrupt(digitalPinToInterrupt(DR_INT0));
  detachInterrupt(digitalPinToInterrupt(DR_INT1));
}

/* -------------------------------------------------------------------------------------------
 */
void updateDisplay(int mode, unsigned int remaining_seconds, unsigned int remaining_seconds_base)  {
  int hours=remaining_seconds/3600;
  int minutes=(remaining_seconds-hours*3600)/60;
  int seconds=remaining_seconds-hours*3600-minutes*60;
  static char buffer[20];
  static float width_percent;

  #if DEBUG
  Serial.println(remaining_seconds);
  #endif
  display.clearDisplay();
  if(mode==RUN_MODE) {
    display.invertDisplay(false);
    snprintf(buffer, 20, "off in\n %1d:%02d:%02d", hours, minutes, seconds);
  } else {
    display.invertDisplay(true);
    snprintf(buffer, 20, "setup\n %1d:%02d:%02d", hours, minutes, seconds);
  }
  if(mode==RUN_MODE) {
    width_percent=BAR_WIDTH/100.0*(100.0/remaining_seconds_base*remaining_seconds);
    display.fillRect(4, 10, width_percent, 18, WHITE);
    display.fillRect(4, 28, 124, 2, WHITE);
  } else {
    display.fillRect(4, 10, remaining_seconds/300, 20, WHITE);  // (upperLeftX, upperLeftY, width, height, WHITE)
  }
  display.setCursor(10, 30);
  display.println(buffer);
  display.display();
}

/* -------------------------------------------------------------------------------------------
 */
void setup()  {
  #if DEBUG
  Serial.begin(115200);
  #endif
  pinMode(DR_INT0, INPUT_PULLUP);
  pinMode(DR_INT1, INPUT_PULLUP);
  pinMode(DR_BTN,  INPUT_PULLUP);
  pinMode(LED_BUILTIN, OUTPUT);
  digitalWrite(LED_BUILTIN, HIGH);    // später das Relais

  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.clearDisplay();
  display.setTextColor(WHITE);
  display.setTextSize(2);

  dr_start();
}

/* -------------------------------------------------------------------------------------------
 */
void loop() {
  static int cnt_old=-1, but, but_old=1, mode=SET_MODE;
  static unsigned int remaining_seconds=dr_counter*SECONDS_PER_STEP;
  static unsigned int remaining_seconds_base;
  static unsigned long start_millis=millis();
  static unsigned int elapsed_seconds=0, elapsed_seconds_old=0;

  if(dr_counter!=cnt_old) {                       // wenn am Drehgeber gedreht wurde
    cnt_old=dr_counter;
    remaining_seconds=dr_counter*SECONDS_PER_STEP;
    updateDisplay(mode, remaining_seconds, remaining_seconds_base);
  }

  if((but=digitalRead(DR_BTN))!=but_old) {        // wenn der Button betätigt oder losgelassen wurde
    but_old=but;
    if(but==LOW) {                                // wenn der Button betätigt wurde
      mode^=1;
      if(mode==RUN_MODE) {
        dr_stop();
        start_millis=millis();
        remaining_seconds_base=remaining_seconds;
      } else {
        dr_counter=min(BAR_WIDTH, max(1, remaining_seconds/long(SECONDS_PER_STEP)+1));
        dr_start();
      }
      updateDisplay(mode, remaining_seconds, remaining_seconds_base);
    }
  }

  if(mode==RUN_MODE) {
    elapsed_seconds=(millis()-start_millis)/1000;
    if(elapsed_seconds!=elapsed_seconds_old) {
      elapsed_seconds_old=elapsed_seconds;
      remaining_seconds=remaining_seconds_base-elapsed_seconds;
      updateDisplay(mode, remaining_seconds, remaining_seconds_base);
      if(remaining_seconds<1)
        digitalWrite(LED_BUILTIN, LOW);
    }
  }
  delay(10);
}
Ausschalttimer

Inhaltsverzeichnis

Vorüberlegungen

FirmwareV1.0

FirmwareV1.1 - Planung

FirmwareV1.1

der ATtiny85 ist raus

Schaltplan - Entwicklungsversion
